实现批处理PING-IP段，并将Ping通的IP段保存到文本

很多人因为工作需要必须ping一个ip段，从而查看IP地址有在运用的状况，在网上下载的一些群PING软件要不被杀毒软件报毒，要不显示結果每一次不一样。

因此我综合了网上各种各样批处理Ping命令后，自己梳理了一个批处理方法，期待能帮助各位有需要的的好朋友，下面我先演示应用全过程，最后给出批处理代码。

1、双击鼠标运行批处理文件，这时会弹出一个命令窗口，规定输入IP段，如果不输入，直接按回车的话，则默认为192.168.16段。

这里我输入我的路由器分派的IP段，192.168.3并按回车

2、然后按规定输入IP地址开始位，如果不输入，立即按回车的话，则默认为1。
这儿我输入10

3、最后按规定输入IP地址结束位，如果不输入，立即按回车的话，则默认为255。
这儿我输入40

4、开始扫描，会显示开始和结束IP地址，以确定以前有沒有输入不正确的地方。
运行的过程中并不会有别的提醒，如果不需要等候进行，可以立即关闭窗口从而提早结束此次扫描。

5、扫描进行后，按任意键退出，窗口会自动关闭。

6、在批处理命令文件所属的文件夹，会转化成相应的文本文件，里边就会有此次扫描的結果（仅纪录ping通的结果）

7、下列为批处理的代码原文，将其保存在文本文件中，把文本文件的后缀名txt替换成bat就可以了。

@echo off
color F0
rem 设置窗口背景色为白色，文字颜色为黑色
title 批处理扫网段
rem 设置窗口标题
echo.
echo 输入你要扫描的IP段，直接按回车则为192.168.16：
set /p IpDuan=
rem 将用户输入赋值给IpDuan变量
if "%IpDuan%"=="" (set IpDuan=192.168.16)
rem 判断IpDuan变量是否赋值，如果为空，则赋值为192.168.16
echo 输入你要扫描的IP起始位，直接按回车则为1：
set /p QiShi=
rem 将用户输入赋值给QiShi变量
if "%QiShi%"=="" (set QiShi=1)
rem 判断QiShi变量是否赋值，如果为空，则赋值为1
echo 输入你要扫描的IP结束位，直接按回车则为255：
set /p JieShu=
rem 将用户输入赋值给JieShu变量
if "%JieShu%"=="" (set JieShu=255)
rem 判断JieShu变量是否赋值，如果为空，则赋值为255
echo 起始IP：%IpDuan%.%QiShi%
rem 显示起始IP
echo 结束IP：%IpDuan%.%JieShu%
rem 显示结束IP
echo ======================================================= >>Ping-%IpDuan%.txt
rem 记录分割线
echo 开始时间：%date%%time% >>Ping-%IpDuan%.txt
rem 记录开始时间
echo 起始IP：%IpDuan%.%QiShi% >>Ping-%IpDuan%.txt
rem 记录起始IP
echo 结束IP：%IpDuan%.%JieShu% >>Ping-%IpDuan%.txt
rem 记录结束IP
echo 正在扫描，请等待...
echo 提前结束请直接关闭窗口
@for /l %%n in (%QiShi%,1,%JieShu%) do @ping -w 600 -n 1 %IpDuan%.%%n|find /i "ttl" >>Ping-%IpDuan%.txt
rem 开始执行
echo 结束时间：%date% %time% >>Ping-%IpDuan%.txt
rem 记录结束时间
echo 扫描完毕,按任意键退出...&pause>nul

8、最后申明一下，本批处理是自己查看了各种各样批处理命令后综合下来的，欢迎大伙儿沟通交流指正。